The conformal Einstein equations

Theoretical introduction

Let ((Overscript[ℳ, ∼]),(OverTilde[g])) be a 4-dimensional space-time, solution of the Einstein eqs (physical spacetime) and consider a conformal embedding of  ((Overscript[ℳ, ∼]),(OverTilde[g])) in another spacetime (ℳ,g) called the unphysical spacetime. We have the relation

({{(OverTilde[g]), ({{ ,  }, {α, β}})}})=(({{g, ({{ ,  }, {α, β}})}})/(Θ^2))

The Einstein equations are not conformally invariant. The transformation of the Einstein tensor under the conformal rescaling reads

({{G[∇], ({{ ,  }, {α, β}})}})=({{G[(OverTilde[∇])], ({{ ,  }, {α, β}})}})-((2 (Subscript[∇, β])(Subscript[∇, α])Θ)/Θ)+({{(OverTilde[g]), ({{ ,  }, {α, β}})}}) (2 Θ (Subscript[∇, γ])(∇^γ)Θ-3 (Subscript[∇, γ])Θ (∇^γ)Θ)

these equations are not regular if Θ=0 (conformal boundary).

We need to carry out a “conformal regularization” if we want to formulate an initial value problem involving the conformally rescaled metric tensor and valid at Θ=0. This regularization is accomplished by the conformal Einstein equations found by H.Friedrich. There are two versions of the conformal equations: the metric conformal equations and the extended conformal equations.

The analysis of these equations enables us to construct explicitly the conformal boundary of known exact solutions of the Einstein equations and study it. This requires the analysis of the Cauchy problem for the conformal equations.

Load of xTensor

<<xAct`xTensor`

Some global settings

<<xAct`ShowTime1`

ApplyRule[expr_]:=MakeRule[Evaluate[List@@expr],MetricOn->All,ContractMetrics->True];

ApplyRuleN[expr_]:=MakeRule[Evaluate[List@@expr]];

Canonicalization without change of covariant derivatives:

$MixedDers=False;

$PrePrint=ScreenDollarIndices;

We define a command used to store the equations we obtain:

$Equations={};

SetAttributes[AddEquation,HoldAll]
AddEquation[expr_Symbol]:=AppendTo[$Equations,Hold[expr]]

Unphysical metric (default)

Definition of a four dimensional  manifold M4:

DefManifold[M4,4,Complement[IndexRange[α,ρ],{π}]]

We define the unphysical metric. This is the default metric which means that indices are always raised and lowered with this metric.

DefMetric[-1,Unphysicalg[-α,-β ],CDg,SymbolOfCovD->{";","∇"},PrintAs->"g"]

SignatureOfMetric@Unphysicalg^={3,1,0};

Physical metric and its relation to the unphysical one

We introduce the physical metric

DefMetric[-1,Physicalg[-α,-β ],CDTildeg,SymbolOfCovD->{";","(OverTilde[∇])"},PrintAs->"(OverTilde[g])"]

PrintAs@InvPhysicalg^="((OverTilde[g])^(#))";

The conformal factor

DefTensor[Θ[],M4]

The unphysical and the physical metric are related as follows

Unphysicalg[-α,-β]==Θ[]^2Physicalg[-α,-β]

UnphysicalToPhysical=%;

AddEquation@UnphysicalToPhysical;

Equal@@(Solve[UnphysicalToPhysical,Physicalg[-α,-β]]//Flatten//First)

PhysicalToUnPhysical=%;

AddEquation@PhysicalToUnPhysical;

Computation of the inverse of the physical metric:

Times[#,Unphysicalg[γ,α]]&/@UnphysicalToPhysical

InvPhysicalg[α,β]==Unphysicalg[α,β]Θ[]^2

InvPhysicalToPhysical=%;

AddEquation@InvPhysicalToPhysical;

Same relation but now with the physical metrics and the indices upstairs:

InvPhysicalToPhysicalUp=(InvPhysicalToPhysical/.ApplyRule@UnphysicalToPhysical)

AddEquation@InvPhysicalToPhysicalUp;

Relation between the unphysical and the physical connections

We start from the relation

UnphysicalToPhysical

We take the unphysical covariant derivative on both sides of this equation.

CDg[-γ]/@%

This relation can be written in terms of the physical covariant derivative as follows

ChangeCovD[#,CDg,CDTildeg]&/@%

expr1=%;

We permute indices cyclically

expr2=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr1

expr3=ReplaceIndex[#,{-α->-β,-β->-γ,-γ->-α}]&/@expr2

0==Last@expr1+Last@expr2-Last@expr3

ToCanonical/@%

This expression enables us to find the value of  ({{Γ[∇,(OverTilde[∇])], ({{d,  ,  }, { , a, c}})}})

Times[#,InvPhysicalg[ε,β]]&/@%

ToCanonical[#,UseMetricOnVBundle->None]&/@%

%/.CDTildeg->CDg

%/.ApplyRuleN@InvPhysicalToPhysical

%/.ApplyRule@PhysicalToUnPhysical

Final expression of the connection tensor:

Equal@@(Solve[%,Union@Cases[%,_ChristoffelCDgCDTildeg,Infinity]]//Flatten//First)

ExpandChristoffelCDgCDTildeg=%;

AddEquation@ExpandChristoffelCDgCDTildeg;

Relation between the unphysical and the physical curvature

This is the relation between the unphysical and the physical curvature

RiemannCDg[-α,-β,-γ,δ]==ChangeCurvature[RiemannCDg[-α,-β,-γ,δ],CDg,CDTildeg]

ChangeCovD[#,CDTildeg,CDg]&/@%

We replace the connection tensors using the result of previous subsection

%/.ApplyRuleN@ExpandChristoffelCDgCDTildeg

ToCanonical/@(ContractMetric[#,AllowUpperDerivatives->True]&/@%)

RiemannUnphysToRiemannPhys=%;

AddEquation@RiemannUnphysToRiemannPhys;

We use this to compute the relation between the Ricci tensors and the scalar curvatures

RiemannUnphysToRiemannPhys/.δ->β

ToCanonical/@(ContractMetric[#,AllowUpperDerivatives->True]&/@%)

RicciUnphysToRicciPhys=%;

AddEquation@RicciUnphysToRicciPhys;

Times[#,InvPhysicalg[α,γ]]&/@ RicciUnphysToRicciPhys

Expand/@%

%/.ApplyRuleN@InvPhysicalToPhysical

ToCanonical/@(ContractMetric[#,AllowUpperDerivatives->True]&/@%)

Solve[%,RicciScalarCDg[]]//Flatten//First

Equal@@%

RicciScalarUnphysToRicciScalarPhys=%;

AddEquation@RicciScalarUnphysToRicciScalarPhys;

EinsteinCDg[-α,-β]==(EinsteinCDg[-α,-β]//EinsteinToRicci)

%/.ApplyRule@RicciScalarUnphysToRicciScalarPhys

%/.ApplyRule@RicciUnphysToRicciPhys

%/.ApplyRule@UnphysicalToPhysical

%/.RicciCDTildeg[-α,-β]->RicciToEinstein[RicciCDTildeg[-α,-β]]

ToCanonical@ContractMetric@%

Simplify/@%

EinsteinUnphysToEinsteinPhys=%;

AddEquation@EinsteinUnphysToEinsteinPhys;

Unphysical Schouten tensor

The Schouten tensor plays a fundamental role in the conformal field equations.

DefTensor[LUnphysg[-α,-β],M4,Symmetric[{-α,-β}],PrintAs->"L"]

LUnphysg[-α,-β]==1/2(RicciCDg[-α,-β]-1/6 RicciScalarCDg[]Unphysicalg[-α,-β])

SchoutenUnphys=%;

AddEquation@SchoutenUnphys;

Equal@@(Solve[SchoutenUnphys,RicciCDg[-α,-β]]//Flatten//First)

RicciCDgToSchouten=%;

AddEquation@RicciCDgToSchouten;

The decomposition of the Riemann tensor into irreducible parts adopts a simpler form if one writes it in terms of the Schouten tensor

RiemannCDg[-α,-β,-γ,δ]==(RiemannCDg[-α,-β,-γ,δ]//RiemannToWeyl)

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@%

RiemannUnphysToSchoutenUnphys=%;

AddEquation@RiemannUnphysToSchoutenUnphys;

Covariant divergence of the Unphysical Weyl tensor in terms of the unphysical Schouten tensor

We start from the second Bianchi identity:

0==ToCanonical@Antisymmetrize[3CDg[-η]@RiemannCDg[-α,-β,-γ,δ],{-η,-α,-β}]

Write the Bianchi identity in terms of the Schouten tensor:

%/.ApplyRule@RiemannUnphysToSchoutenUnphys

ToCanonical/@%

AntisCovDivWeylUnphysical=%;

AddEquation@AntisCovDivWeylUnphysical;

AntisCovDivWeylUnphysical/.δ->η

ToCanonical/@(ContractMetric/@%)

Solve[%,CDg[-η]@WeylCDg[-α,-β,-γ,η]]//Flatten

Equal@@First@%

CovDivWeylUnphysical=%

AddEquation@CovDivWeylUnphysical;

The trace of this equation yields a relation involving the covariant divergence of the Schouten tensor

CovDivWeylUnphysical/.-β->γ

ToCanonical/@(ContractMetric/@%)

Solve[%,CDg[-γ]@LUnphysg[-α,γ]]//Flatten//First

Equal@@%

We declare this as an automatic rule

AutomaticRules[LUnphysg,ApplyRule@%]

CovDivWeylUnphysical=ToCanonical/@CovDivWeylUnphysical

Physical Schouten tensor

We define the Schouten tensor with respect to the physical metric:

DefTensor[LPhysg[-α,-β],M4,Symmetric[{-α,-β}],PrintAs->"(OverTilde[L])"]

LPhysg[-α,-β]==1/2(RicciCDTildeg[-α,-β]-1/6 RicciScalarCDTildeg[]Physicalg[-α,-β])

SchoutenPhys=%;

AddEquation@SchoutenPhys;

Solve[SchoutenPhys,RicciCDTildeg[-α,-β]]//Flatten

Equal@@First@%

RicciCDTildegToSchoutenPhys=%;

AddEquation@RicciCDTildegToSchoutenPhys;

Relation between the  unphysical Schouten tensor and the physical Schouten tensor

The relation between the physical and unphysical Schouten tensors is the starting point for the derivation of the metric conformal equations.

SchoutenUnphys

%/.ApplyRuleN@RicciUnphysToRicciPhys

%/.ApplyRuleN@RicciScalarUnphysToRicciScalarPhys

%/.ApplyRuleN@RicciCDTildegToSchoutenPhys

ToCanonical/@(ContractMetric[#,AllowUpperDerivatives->True]&/@%)

%/.ApplyRuleN@PhysicalToUnPhysical

SchoutenUnphysicalToSchoutenPhysical=%;

AddEquation@SchoutenUnphysicalToSchoutenPhysical;

Metric conformal field equations

Henceforth, we assume that we work in an Einstein space

EinsteinMetric=RicciCDTildeg[-α,-β]==1/4RicciScalarCDTildeg[]Physicalg[-α,-β]

AddEquation@EinsteinMetric;

Derivation of the relation (Subscript[∇, b])({{Σ, ({{ }, {a}})}})==s ({{g, ({{ ,  }, {a, b}})}})-({{L, ({{ ,  }, {a, b}})}}) Θ

Start from the identity:

SchoutenUnphysicalToSchoutenPhysical

Solve[%,CDg[-β]@CDg[-α]@Θ[]]//Flatten//First

Equal@@%

%/.ApplyRule@SchoutenPhys

ToCanonical/@%

We impose now that we are in an Einstein manifold

%/.ApplyRule@EinsteinMetric

%/.IndexSolve[RicciScalarUnphysToRicciScalarPhys,RicciScalarCDTildeg[]]

%/.ApplyRuleN@PhysicalToUnPhysical

ToCanonical/@(ContractMetric/@%)

Collect[#,Unphysicalg[-α,-β]]&/@%

CDg2θ=%;

AddEquation@CDg2θ;

We rewrite this equation in terms of new quantities:

DefTensor[sUnphys[],M4,PrintAs->"s"];DefTensor[ΣUnphys[-α],M4,PrintAs->"Σ"];

Friedrich scalar:

sUnphys[]==CDg2θ[[-1,-1,-1]]

ExpandsUnphys=%;

AddEquation@ExpandsUnphys;

Covariant derivative of the conformal factor:

CDgΘ=CDg[-α]@Θ[]==ΣUnphys[-α]

AddEquation@CDgΘ;

So we have that the relation CDg2θ takes the form

CDg2θ/.IndexSolve[ExpandsUnphys,RicciScalarCDg[]]/.ApplyRule@CDgΘ

ToCanonical/@%

Conf1=%;

AddEquation@Conf1;

Relation (Subscript[∇, a])s==-({{L, ({{ ,  }, {a, b}})}}) ({{Σ, ({{b}, { }})}})

Work out the covariant derivative of the Friedrich scalar s:

CDg[-α]@sUnphys[]==(CDg[-α]@sUnphys[]/.ApplyRule@ExpandsUnphys)

%//SortCovDs

%/.ApplyRule@CDgΘ

%/.ApplyRule@Conf1

%/.ApplyRule@CDgΘ

ToCanonical/@%

Solve[%,CDg[-α]@sUnphys[]]//Flatten

Equal@@First@%

%/.ApplyRule@SchoutenUnphys

ToCanonical/@(ContractMetric/@%)

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@(ContractMetric/@%)

CDgSUnphys=%;

AddEquation@CDgSUnphys;

Integrability condition of  (Subscript[∇, b])({{Σ, ({{ }, {a}})}})==s ({{g, ({{ ,  }, {a, b}})}})-({{L, ({{ ,  }, {a, b}})}}) Θ  => Relation ({{𝒹, ({{ ,  ,  ,  }, {a, c, b, d}})}}) ({{Σ, ({{d}, { }})}})+(Subscript[∇, a])({{L, ({{ ,  }, {b, c}})}})-(Subscript[∇, c])({{L, ({{ ,  }, {a, b}})}})==0

We start from the condition

CDg[-γ]@CDg[-α]@ΣUnphys[-β]-CDg[-α]@CDg[-γ]@ΣUnphys[-β]==(CDg[-γ]@CDg[-α]@ΣUnphys[-β]-CDg[-α]@CDg[-γ]@ΣUnphys[-β]//SortCovDs)

We know the covariant derivative of ({{Σ, ({{ }, {b}})}}) so we replace it

%/.ApplyRule@Conf1

%/.ApplyRule@CDgΘ

%/.ApplyRule@Conf1

%/.ApplyRule@CDgSUnphys

ToCanonical/@%

RiemannToWeyl/@%

%/.ApplyRule@RicciCDgToSchouten

ToCanonical/@(ContractMetric/@%)

First@%-Last@%==0

ToCanonical/@%

Int1=%;

AddEquation@Int1;

This is best expressed in terms of the "rescaled Weyl tensor"

DefTensor[𝒹[-δ,-α,-β,-γ],M4,RiemannSymmetric[{-δ,-α,-β,-γ}]]

By definition

RescaledWeylUnphys=𝒹[-δ,-α,-β,-γ]==WeylCDg[-δ,-α,-β,-γ]/Θ[]

Solve[RescaledWeylUnphys,WeylCDg[-δ,-α,-β,-γ]]//Flatten

Equal@@First@%

WeylToRescaledWeylUnphys=%;

AddEquation@WeylToRescaledWeylUnphys;

Also ({{𝒹, ({{ ,  ,  ,  }, {d, a, b, c}})}}) is traceless

AutomaticRules[𝒹,ApplyRule[𝒹[α,-β,-α,-γ]==0]]

So the integrability condition takes the following form

Int1/.ApplyRule@WeylToRescaledWeylUnphys

Times[#,1/Θ[]]&/@%

Expand/@%

Conf3=%;

AddEquation@Conf3;

For later use, we rewrite this condition as follows:

Conf3/.𝒹[-a_,-b_,-c_,-d_]ΣUnphys[d_]:>Hold[𝒹[-a,-b,-c,-d]ΣUnphys[d]]

Solve[%,Union@Cases[%,_Hold,Infinity]]//Flatten//ReleaseHold

Equal@@First@%

ReConf3=%;

AddEquation@ReConf3;

Covariant divergence of the rescaled Weyl tensor

We compute now the covariant divergence of the rescaled Weyl tensor:

CDg[-α]@𝒹[α,-β,-γ,-δ]==(CDg[-α]@𝒹[α,-β,-γ,-δ]/.ApplyRule@RescaledWeylUnphys)

%/.ApplyRule@CovDivWeylUnphysical

%/.ApplyRule@WeylToRescaledWeylUnphys

%/.ApplyRule@CDgΘ

%/.ApplyRule@ReConf3

ToCanonical/@%

Conf4=%;

AddEquation@Conf4;

Integrability conditions of (Subscript[∇, a])s==-({{L, ({{ ,  }, {a, b}})}}) ({{Σ, ({{b}, { }})}}) => identically fulfilled.

As the connection ∇ has no torsion,  the quantity (Subscript[∇, b])(Subscript[∇, a])s must be symmetric in the indices b,a

0==CDg[-β]@CDg[-α]@sUnphys[]-CDg[-α][CDg[-β]@sUnphys[]/.ApplyRule@CDgSUnphys]

%/.ApplyRule@CDgSUnphys

%/.ApplyRule@Conf1

ToCanonical/@%

This relation is implied by one of the conformal field equations as we explicitly check, so it gives no new conditions:

Times[#,ΣUnphys[β]]&/@Conf3

ToCanonical/@%

Summary (set of  “metric conformal field equations”)

This is the list of "metric conformal field equations" in an Einstein spacetime:

MetricConformalEquations={CDgΘ,Conf1,CDgSUnphys,Conf3,Conf4}

%//Length

AddEquation@MetricConformalEquations;

This is a hyperbolic system for the following variables:

{Θ[],ΣUnphys[-α],sUnphys[],Unphysicalg[-α,-β],LUnphysg[-α,-β],𝒹[-δ,-γ,-β,α]}

Exercises

Exercise 1

Prove that the following quantity is an integration constant of the vacuum metric conformal field equations:

IntegrationConstant=6Θ[] sUnphys[]-3CDg[-α]@Θ[]CDg[α]@Θ[]

Can you tell the actual value of the integration constant?

Answer

We compute the covariant derivative of the purported integration constant:

CDg[-β]@IntegrationConstant

Use here the metric conformal equations:

%/.ApplyRule@MetricConformalEquations[[1]]

%/.ApplyRule@MetricConformalEquations[[2]]

%/.ApplyRule@MetricConformalEquations[[3]]

ToCanonical@ContractMetric@%

Computation of the value of the integration constant:

IntegrationConstant/.ApplyRule@ExpandsUnphys

%/.ApplyRule@RicciScalarUnphysToRicciScalarPhys

ToCanonical@%

This is a constant because we are working in an Einstein space.